3. Configuration examples

/*
 * Simply commented example of a tcng traffic control file.
 *
 *   Martin A. Brown <mabrown@securepipe.com>
 *
 * Example:  Using class selection path.
 *
 * (If you are reading the processed output in HTML, the callouts are
 *  clickable links to the description text.)
 *
 */

#include "fields.tc"     
#include "ports.tc"

#define INTERFACE  eth0  

dev INTERFACE {
    egress { 

        /* In class selection path, the filters come first!  DSmark */ 

        class ( <$ssh> )    if tcp_sport ==  22 && ip_tos_delay == 1 ;
        class ( <$audio> )  if tcp_sport == 554 || tcp_dport == 7070 ;
        class ( <$bulk> ) \
            if tcp_sport == PORT_SSH || tcp_dport == PORT_HTTP ; 
        class ( <$other> )  if 1 ; 

        /* section in which we configure the qdiscs and classes */ 

        htb () { 
            class ( rate 600kbps, ceil 600kbps ) { 
                $ssh   = class ( rate  64kbps, ceil 128kbps ) { sfq; } ; 
               $audio = class ( rate 128kbps, ceil 128kbps ) { sfq; } ;
                $bulk  = class ( rate 256kbps, ceil 512kbps ) { sfq; } ;
                $other = class ( rate 128kbps, ceil 384kbps ) { sfq; } ; 
            }
        }
    }
}
      

/*
 * Simply commented example of a tcng traffic control file.
 *
 *   Martin A. Brown <mabrown@securepipe.com>
 *
 * Example:  Using a meter.
 *
 * (If you are reading the processed output in HTML, the callouts are
 *  clickable links to the description text.)
 *
 */

#define   EXCEPTION      192.168.137.50
#define   INTERFACE      eth0

$meter = trTCM( cir 128kbps, cbs 10kB, pir 256kbps, pbs 10kB );  

dev eth0 {
    egress {
        class ( <$full> )     if ip_src == EXCEPTION      ; 
        class ( <$fast> )     if trTCM_green( $meter )    ; 
        class ( <$slow> )     if trTCM_yellow( $meter )   ; 
        drop                  if trTCM_red( $meter )      ; 
        htb {
            class ( rate 600kbps, ceil 600kbps ) {
                $fast = class ( rate 256kbps, ceil 256kbps ) { sfq; } ;
                $slow = class ( rate 128kbps, ceil 128kbps ) { sfq; } ;
                $full = class ( rate 600kbps, ceil 600kbps ) { sfq; } ;
            }
        }
    }
}